# Nvidia driver issues for certain apps

**URL:** <https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134>\
**Category:** Guix\
**Created:** [November 6, 2026, 3:20am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134 "2026-11-06T03:20:11Z")\
**Posts on this page:** 6\
**Page:** 1

<div class="post-metadata">

**Author:** ![vivi](https://yyz1.discourse-cdn.com/flex029/user_avatar/forum.systemcrafters.net/vivi/32/1284_2.png) [@vivi](https://forum.systemcrafters.net/u/vivi)\
**Post date:** [November 6, 2026, 3:20am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134/1 "2026-11-06T03:20:11Z")

</div>

I am unfortunately running into issues with a brand new nonguix setup, and with an Nvidia card.

I have followed the instructions to add the nvidia transformation to both my OS and Home setups, and that seems to work fine. In fact, it seems some apps are working properly with Nvidia:

- Blender seems to be fine.
- KDE Plasma seems fine
- Firefox _from within Flatpak only_ works great.

However, I am having significant issues with many of the apps I’ve tried to directly install via my (non)guix home configuration, which again is wrapped in the nvidia transformation:

- Firefox - No hardware acceleration, so scrolling is sluggish and WebGL is software rendered and choppy.

- Chrome - Scrolling is sluggish, WebGL entirely broken, causes a crash in the JS because it can’t make a surface

- Luanti/minetest - Crashes at boot with glx errors

- glxgears - Crashes at boot with glx errors

- glxinfo - Crashes at boot:

I am sure there are other apps with issues as well but I have stopped trying at that point.

So something seems to be off with the driver, even though when I run some diagnostics it does register that the driver is the `nvidia` open source driver.

Are there any pointers I can have to get me going? Here’s my config:

```scheme
(define-module (vv machines lily)
  #:use-module (vv home common)
  #:use-module (vv home pipewire)
  #:use-module (gnu)
  #:use-module (gnu bootloader)
  #:use-module (gnu home)
  #:use-module (gnu home services sound)
  #:use-module (gnu packages)
  #:use-module (gnu services)
  #:use-module (gnu services base)
  #:use-module (gnu services cups)
  #:use-module (gnu services desktop)
  #:use-module (gnu services games)
  #:use-module (gnu services pm)
  #:use-module (gnu services virtualization)
  #:use-module (gnu services sddm)
  #:use-module (gnu services sound)
  #:use-module (gnu services xorg)
  #:use-module (gnu system)
  #:use-module (gnu system accounts)
  #:use-module (gnu system file-systems)
  #:use-module (gnu system mapped-devices)
  #:use-module (nonguix transformations)
  #:use-module (nongnu packages linux)
  #:use-module (nongnu packages nvidia)
  #:use-module (nongnu system linux-initrd)
  #:export (lily-os lily-home))

(define* (package-with-pw-wrapper pkg #:optional (program (package-name pkg)))
  (package
    (name (package-name pkg))
    (version (package-version pkg))
    (source #f)
    (build-system trivial-build-system)
    (arguments
     (list
      #:modules '((guix build union)
                  (guix build utils))
      #:builder
      #~(begin
          (use-modules (ice-9 match)
                       (guix build union)
                       (guix build utils))
          (let* ((program (string-append #$output "/bin/" #$program))
                 (desktop (string-append #$output "/share/applications/"
                                         #$program ".desktop"))
                 (pw-lib (string-append #$pipewire "/lib")))
            (union-build #$output (list #$pkg)
                         #:create-all-directories? #t)
            (when (file-exists? desktop)
              (substitute* desktop
                (("Exec=.*")
                 (string-append "Exec=" program "\n"))))
            (wrap-program program
              #:sh (string-append #$bash-minimal "/bin/sh")
              `("LD_LIBRARY_PATH" ":" prefix (,pw-lib)))))))
    (synopsis (package-synopsis pkg))
    (description (package-description pkg))
    (home-page (package-home-page pkg))
    (license (package-license pkg))))

(define nvidia-transform
  (nonguix-transformation-nvidia
   #:driver nvda-595
   #:configure-xorg? sddm-service-type))

(define lily-os
  (nvidia-transform
   (operating-system
     (locale "en_US.utf8")
     (timezone "America/New_York")
     (keyboard-layout (keyboard-layout "us"))
     (host-name "lily")
     (bootloader (bootloader-configuration
                  (bootloader grub-efi-bootloader)
                  (targets (list "/boot/efi"))
                  (keyboard-layout keyboard-layout)))
     (kernel linux)
     (initrd microcode-initrd)
     (firmware (list sof-firmware linux-firmware))
     (users (cons* (user-account
                    (name "vv")
                    (comment "Vivianne Langdon")
                    (group "users")
                    (home-directory "/home/vv")
                    (supplementary-groups
                     '("audio"
                       "kvm" ; for VMs
                       "lp" ; for bluetooth
                       "netdev"
                       "realtime" ; for realtime prioritization
                       "video"
                       "docker"
                       "wheel"))) ; for sudo
                   %base-user-accounts))
     (groups (cons* (user-group
                     (name "realtime")
                     (system? #t))
                    (user-group
                     (name "docker")
                     (system? #t))
                    %base-groups))
     (packages %base-packages)
     (services (modify-services
	                 (cons* (service plasma-desktop-service-type)
                          (service bluetooth-service-type)
                          (service thermald-service-type)
                          (service cups-service-type
                                   (cups-configuration
                                    (web-interface? #t)
                                    (extensions
			                               (map specification->package '("cups-filters" "brlaser")))))
		                      (service pam-limits-service-type
			                             (list
			                              (pam-limits-entry "@realtime"
					                                            'both 'rtprio 99)
			                              (pam-limits-entry "@realtime"
					                                            'both 'memlock 'unlimited)))
                          (service sddm-service-type)
                          %desktop-services)
                 (delete gdm-service-type)
	               (delete pulseaudio-service-type)
                 (guix-service-type config =>
                                    (guix-configuration
                                     (inherit config)
                                     (substitute-urls
                                      (append (list "https://substitutes.nonguix.org")
                                              %default-substitute-urls))
                                     (authorized-keys
                                      (append (list (local-file "../../keys/nonguix-signing-key.pub"))
                                              %default-authorized-guix-keys))))))
     (mapped-devices (list (mapped-device
                            (source (uuid "547c83f0-9677-47c0-905a-bacef422090d"))
                            (target "cryptroot")
                            (type luks-device-mapping))))
     (file-systems (cons* (file-system
                            (mount-point "/boot/efi")
                            (device (uuid "2185-15D5" 'fat32))
                            (type "vfat"))
                          (file-system
                            (mount-point "/")
                            (device "/dev/mapper/cryptroot")
                            (type "btrfs")
                            (dependencies mapped-devices)))
                          %base-file-systems))
     (name-service-switch %mdns-host-lookup-nss))))

(define lily-home
  (nvidia-transform
   (home-environment
    (packages
     (cons* (package-with-pw-wrapper (specification->package "firefox"))
            (specifications->packages
             '("audacity"
               "blender"
               "cmake"
               "direnv"
               "dragonfly-reverb"
               "easyeffects"
               "emacs"
               "emacs-guix"
               "fennel"
               "ffmpeg-nvidia@595"
               "fish"
               "flatpak"
               "font-google-noto-emoji"
               "font-google-noto-sans-cjk"
               "font-google-noto-serif-cjk"
               "font-inconsolata"
               "fzf"
               "gajim"
               "ghc"
               "gimp"
               "git"
               "git-annex"
               "go"
               "google-chrome-stable"
               "guile-colorized"
               "guile-hall"
               "guile-hoot"
               "guile-proba"
               "guile-readline"
               "haunt"
               "htop"
               "imagemagick"
               "inkscape"
               "janet"
               "libreoffice"
               "libresprite"
               "lsp-plugins"
               "lua"
               "m8c"
               "milkytracker"
               "mpv-nvidia"
               "ncurses"
               "node"
               "obs-nvidia"
               "openssh"
               "pavucontrol"
               "pipx"
               "projectm"
               "qjackctl"
               "qpwgraph"
               "racket"
               "rust"
               "schismtracker"
               "sfxr"
               "starship"
               "steam-nvidia@595"
               "strace"
               "supercollider"
               "tor"
               "vlc"
               "wine"
               "x42-plugins"
               "xdg-desktop-portal"
               "xdg-desktop-portal-gtk"
               "zig"
               "zoxide"
               "yt-dlp"))))
    (services (cons (service home-pipewire-service-type)
                    common-services)))))

lily-os

```

---

<div class="post-metadata">

**Author:** ![vivi](https://yyz1.discourse-cdn.com/flex029/user_avatar/forum.systemcrafters.net/vivi/32/1284_2.png) [@vivi](https://forum.systemcrafters.net/u/vivi)\
**Post date:** [November 6, 2026, 3:21am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134/2 "2026-11-06T03:21:47Z")

</div>

And:

```auto
vv@lily ~$ inxi -G
Graphics:
  Device-1: NVIDIA GA104 [GeForce RTX 3070 Lite Hash Rate] driver: nvidia
    v: 595.112.07
  Display: wayland server: N/A compositor: kwin_wayland driver: X:
    loaded: nvidia unloaded: fbdev,modesetting,nouveau,nv,vesa
    gpu: nv_platform,nvidia,nvidia-nvswitch resolution: 1: 3840x2160~60Hz
    2: 1920x1080~60Hz
  API: EGL v: 1.5 drivers: N/A platforms: wayland,x11
  API: OpenGL Message: No GL data available.
  Info: Tools: api: eglinfo,glxinfo de: kscreen-console,kscreen-doctor
    gpu: nvidia-settings,nvidia-smi wl: wayland-info
    x11: xdpyinfo, xprop, xrandr

```

---

<div class="post-metadata">

**Author:** ![vivi](https://yyz1.discourse-cdn.com/flex029/user_avatar/forum.systemcrafters.net/vivi/32/1284_2.png) [@vivi](https://forum.systemcrafters.net/u/vivi)\
**Post date:** [November 6, 2026, 3:49am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134/3 "2026-11-06T03:49:34Z")

</div>

I have _just_ seen that the 595 driver has been deprecated. Pulling now, really hope that fixes things…

---

<div class="post-metadata">

**Author:** ![vivi](https://yyz1.discourse-cdn.com/flex029/user_avatar/forum.systemcrafters.net/vivi/32/1284_2.png) [@vivi](https://forum.systemcrafters.net/u/vivi)\
**Post date:** [November 6, 2026, 4:20am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134/4 "2026-11-06T04:20:52Z")

</div>

Okay! I think I have sorted it out. It was three things:

- The custom Firefox pipewire profile that I snarfed from @dthompson is not nvidia-aware – presumably there is some modification that I would have to do, if that is even still necessary. I switched to a standard firefox, _and logged in again,_ and it works!
- Seems I was not properly wrapping apps that I installed using `guix install`. I have switched to adding them via the profile and it works properly now. I think there’s some steps that are in the nonguix README that I can follow if I need to install 3d apps one-off for the future. I had mistakenly thought that if I was using a guix home configured with the nvidia transformation, that even `guix install` would auto-wrap the packages, but I seem to have been mistaken.
- For Chrome, I had to add the flag `--use-webgpu-adapter=opengles` in order to disable Vulkan, which for some reason doesn’t work

So happy to have it all working as expected now.

---

<div class="post-metadata">

**Author:** ![vivi](https://yyz1.discourse-cdn.com/flex029/user_avatar/forum.systemcrafters.net/vivi/32/1284_2.png) [@vivi](https://forum.systemcrafters.net/u/vivi)\
**Post date:** [November 6, 2026, 4:21am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134/5 "2026-11-06T04:21:50Z")

</div>

I think the Chrome issue is:

```auto
[5080:5080:1105/232129.703477:ERROR:ui/ozone/platform/wayland/gpu/wayland_surface_factory.cc:248] '--ozone-platform=wayland' is not compatible with Vulkan. Consider switching to '--ozone-platform=x11' or disabling Vulkan

```

---

<div class="post-metadata">

**Author:** ![vivi](https://yyz1.discourse-cdn.com/flex029/user_avatar/forum.systemcrafters.net/vivi/32/1284_2.png) [@vivi](https://forum.systemcrafters.net/u/vivi)\
**Post date:** [November 6, 2026, 4:32am UTC](https://forum.systemcrafters.net/t/nvidia-driver-issues-for-certain-apps/2134/6 "2026-11-06T04:32:21Z")

</div>

Indeed: If I add `--use-webgpu-adapter=opengles` to the chrome launch args, my test fluid simulation is smooth as butter again.